Minim core | ugens | analysis |
Oscil Fields amplitude frequency offset phase Methods channelCount ( ) getLastValues ( ) getWaveform ( ) patch ( ) printInputs ( ) reset ( ) sampleRate ( ) setAmplitude ( ) setChannelCount ( ) setFrequency ( ) setPhase ( ) setSampleRate ( ) setWaveform ( ) tick ( ) unpatch ( ) | An Oscil is a UGen that generates audio by oscillating over a Waveform at a particular frequency. For instance, if you were to create this Oscil:
    Oscil testTone = new Oscil( 440, 1, Waves.SINE );
When patched to an AudioOuput, it would generate a continuous sine wave tone at 440 Hz and would sound like a test tone. This frequency also happens to be the same as the pitch played by the lead oboist in a orchestra when they tune up at the beginning of a concert. However, rather than give Oscil a fixed, or limited, set of sounds it can generate, instead it simply oscillates over a generic Waveform object. Waveform is simply an interface that declares a value method, which is used by Oscil to determine what value it should output at any given moment in time. Generally, you will use predefined Waveforms from the Waves class, or generated Waveforms using the WavetableGenerator class. However, there's no particular reason you couldn't define your own classes that implement the Waveform interface. Another abstraction the Oscil UGen makes use of is the Frequency class. This class allows you to define a frequency in terms of pitch, midi note, or hertz. This is often quite useful when writing musical scores with code. For instance, we could use the Frequency class when creating an Oscil that will sound the same as the example above:
    Oscil testTone = new Oscil( Frequency.ofPitch("A4"), 1, Waves.SINE );
Constructors
    Constructs an Oscil UGen, given frequency in Hz, amplitude, and a waveform
    Oscil(float frequencyInHertz, float amplitude, Waveform waveform)
    Constructs an Oscil UGen given frequency in Hz and amplitude. This
     oscillator uses a sine wave.
    Oscil(float frequencyInHertz, float amplitude)
    Constructs an Oscil UGen given a Frequency and amplitude. This oscillator
     uses a sine wave.
    Oscil(Frequency frequency, float amplitude)
    Constructs an Oscil UGen given a Frequency, amplitude, and a waveform
    Oscil(Frequency frequency, float amplitude, Waveform waveform)
Parameters frequencyInHertz — float: the frequency this Oscil should oscillate at amplitude — float: the amplitude of this Oscil. waveform — Waveform: the waveform this Oscil will oscillate over frequency — Frequency: the frequency this Oscil should oscillate at. Related UGen Waveform Waves WavetableGenerator Frequency Example
    /**
      * This sketch demonstrates how to create synthesized sound with Minim
      * using an AudioOutput and an Oscil. An Oscil is a UGen object,
      * one of many different types included with Minim. By using
      * the numbers 1 thru 5, you can change the waveform being used
      * by the Oscil to make sound. These basic waveforms are the
      * basis of much audio synthesis.
      *
      * For many more examples of UGens included with Minim,
      * have a look in the Synthesis folder of the Minim examples.
      * <p>
      * For more information about Minim and additional features,
      * visit http://code.compartmental.net/minim/
      */

    import ddf.minim.*;
    import ddf.minim.ugens.*;

    Minim       minim;
    AudioOutput out;
    Oscil       wave;

    void setup()
    {
      size(512, 200, P3D);

      minim = new Minim(this);

      // use the getLineOut method of the Minim object to get an AudioOutput object
      out = minim.getLineOut();

      // create a sine wave Oscil, set to 440 Hz, at 0.5 amplitude
      wave = new Oscil( 440, 0.5f, Waves.SINE );
      // patch the Oscil to the output
      wave.patch( out );
    }

    void draw()
    {
      background(0);
      stroke(255);
      strokeWeight(1);

      // draw the waveform of the output
      for(int i = 0; i < out.bufferSize() - 1; i++)
      {
        line( i, 50  - out.left.get(i)*50,  i+1, 50  - out.left.get(i+1)*50 );
        line( i, 150 - out.right.get(i)*50, i+1, 150 - out.right.get(i+1)*50 );
      }

      // draw the waveform we are using in the oscillator
      stroke( 128, 0, 0 );
      strokeWeight(4);
      for( int i = 0; i < width-1; ++i )
      {
        point( i, height/2 - (height*0.49) * wave.getWaveform().value( (float)i / width ) );
      }
    }

    void mouseMoved()
    {
      // usually when setting the amplitude and frequency of an Oscil
      // you will want to patch something to the amplitude and frequency inputs
      // but this is a quick and easy way to turn the screen into
      // an x-y control for them.

      float amp = map( mouseY, 0, height, 1, 0 );
      wave.setAmplitude( amp );

      float freq = map( mouseX, 0, width, 110, 880 );
      wave.setFrequency( freq );
    }

    void keyPressed()
    {
      switch( key )
      {
        case '1':
          wave.setWaveform( Waves.SINE );
          break;

        case '2':
          wave.setWaveform( Waves.TRIANGLE );
          break;

        case '3':
          wave.setWaveform( Waves.SAW );
          break;

        case '4':
          wave.setWaveform( Waves.SQUARE );
          break;

        case '5':
          wave.setWaveform( Waves.QUARTERPULSE );
          break;

        default: break;
      }
    }
Usage Web & Application