VZ "SPACER" game for the 2020 Ten-Liner game.
=============================  Bushy - 05/02/2020 ======



==========================
Overview
==========================

You,  Commanding  Officer  Roger  Wilco  wakes  up 
in   Space   Quest   48,  the    Rainbow  Revenge.
You must successfully navigate  your space ship to 
the bad cybermen whom appear as a digit in amongst 
the alien rainbow universe.
Using the keyboard controls, fly your  ship to run 
over the nasty cybermen,killing them dead in their 
path, and saving  the  colouful  rainbow universe.

As a reward you    collect   a   random  amount of 
buckazoids, but you also loose a life because  the 
universe is like that. Depending on the  time that
you take to run over the cybermen ship, you  might 
automatically be transferred to somewhere else  in
the universe for forces far beyond you or I.   You 
will also loose a life.

After ten rounds, your battle  is finally over and 
you  can  retire on your savings of  Buck-a-zoids.




==========================
To RUN
==========================

This demo was developed and tested on the two VZ200 emulators : MAME or VZEM
Download and install either emulator :

MAME	: https://www.mamedev.org/release.php
VZEM	: http://www.vz200.org


Load the 'SPACER.VZ' snapshot in.
Type 'RUN'




==========================
KEYBOARD CONTROLS
==========================

Q	: UP
A	: DOWN
M	: LEFT	  ( M and comma may seem a weird choice at first, but these are  )
,	: RIGHT   ( the traditional keys for the VZ200/VZ300 keyboard arrow keys )
                  ( You will find most VZ games utilise these keys.              )



==========================
LISTING
==========================


0 GOSUB8:POKE30777,1:FORZ=1TO10:L=28704:FORD=LTO29183STEP32
1 E=(RND(7)*16)+143:FORF=DTOD+31:POKEF,E:NEXTF,D:M=32:A=1
2 POKE28715+RND(468),RND(9)+49
3 W=L:A$=INKEY$:IFA$=",",L=L+1:M=62:ELSEIFA$="M",L=L-1:M=60
4 IFA$="Q"ANDL>28736,L=L-32:M=30
5 IFA$="A"ANDL<29151,L=L+32:M=22
6 Q=PEEK(L):IFQ>48ANDQ<58,S=S+Q:GOTO8:ELSEPOKEW,32:POKEL,M
7 IFRND(400)<397,3
8 CLS:PRINT@0,"SCORE:";S,"LIVES:";10-Z:SOUND31,2:IFA=0,RETURN
9 NEXT:PRINT@102,"THE BATTLE IS OVER!":SOUND24,1;21,1;18,1;15,5



==========================
Detailed description
==========================

Line 0 : call line 3. Disable interrupts for basic. Loop ten lives. 
         Outter Loop to display rainbow background.

Line 1 : Inner loop for rainbow display. Set ship direction screen character. 
         Turn off return-calling from line 8 for future use.

Line 2 : Display a random number (Cybermen ship) in a random screen location.

Line 3 : Keyboard read. Deal with Left and Right. Direction and on-screen display ship character.

Line 4 : Keyboard Up, and check that it stays on screen. Do direction and on-screen ship character.

Line 5 : Keyboard down, and check that it stays on screen. Do direction and on-screen ship character.
       : Due to line length, can not combine line 5 with line 4. TWO CHARACTERS too short !

Line 6 : Collision detection. Find location of ship, if it equals cybermen ship add score and jump to
         line 8 and return to Line 0 via Line 8 NEXT to start a new round.
       : If there was no collision, blank out your trailing ship nuclear radiation debris and display 
         your ship new location with automated updated character navigation direction display.

Line 7 : Random amount of time elapsed before you are transferred to anothe rpart of the rainbow universe.

Line 8 : Clear screen, display score and lives.
 
Line 9 : End of Main_Game_TEN-LIVES_Loop. Display Battle is over, and sound off theme.





