/****************************************************************************
**
** Copyright (C) 2014 NVIDIA Corporation.
** Copyright (C) 2019 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of Qt 3D Studio.
**
** $QT_BEGIN_LICENSE:GPL$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/

float calculateRoughness( in vec3 N, in float roughnessU, in float roughnessV, in vec3 tangentU )
{
  float roughness = roughnessU;
  if ( abs(roughnessU - roughnessV) > 0.00001)
  {
    // determine major and minor radii a and b, and the vector along the major axis
    float a = roughnessU;
    float b = roughnessV;

    // we need the angle between the major axis and the projection of viewDir on the tangential plane
    // the major axis is the orthonormalization of tangentU with respect to N
    // the projection of viewDir is the orthonormalization of viewDir with respect to N
    // as both vectors would be calculated by orthonormalize, we can as well leave the second cross
    // product in those calculations away, as they don't change the angular relation.
    vec3 minorAxis = normalize( cross( tangentU, N ) );   // crossing this with N would give the major axis
                                                          // which is equivalent to orthonormalizing tangentU with respect to N
    if ( roughnessU < roughnessV )
    {
      a = roughnessV;
      b = roughnessU;
      minorAxis = cross( N, minorAxis );
    }

    vec3 po = normalize( cross( viewDir, N ) );
    float cosPhi = dot( po, minorAxis );

    // determine the polar coordinate of viewDir, take that radius as the roughness
    float excentricitySquare = 1.0 - square( b / a );
    roughness = b / sqrt( 1.0 - excentricitySquare * square( cosPhi ) );
  }
  return( roughness );
}

