Plug & Paint Example | Qt Widgets 5.13.0

Qt 5.13 | Qt Widgets | Plug & Paint Example

Qt 5.13.0 Reference Documentation

# Plug & Paint Example

      TARGET = plugandpaint
      DESTDIR = ..

      QT += widgets

      HEADERS        = interfaces.h \
                       mainwindow.h \
                       paintarea.h \
                       plugindialog.h
      SOURCES        = main.cpp \
                       mainwindow.cpp \
                       paintarea.cpp \
                       plugindialog.cpp

      LIBS           = -L../plugins

      macx-xcode {
          LIBS += -lpnp_basictools$($${QMAKE_XCODE_LIBRARY_SUFFIX_SETTING})
      } else {
          LIBS += -lpnp_basictools
          if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
              mac:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)_debug
              win32:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)d
          }
      }

      # install
      target.path = $$[QT_INSTALL_EXAMPLES]/widgets/tools/plugandpaint
      INSTALLS += target

      CONFIG += install_ok  # Do not cargo-cult this!