pathview-example.qml Example File | Qt Quick 5.12.10

- Qt 5.12
- Qt Quick
- Qt Quick Examples - Views
- pathview-example.qml Example File
- Qt 5.12.10 Reference Documentation

# pathview-example.qml Example File

views/pathview/pathview-example.qml

     /****************************************************************************
     **
     ** Copyright (C) 2017 The Qt Company Ltd.
     ** Contact: https://www.qt.io/licensing/
     **
     ** This file is part of the examples of the Qt Toolkit.
     **
     ** $QT_BEGIN_LICENSE:BSD$
     ** Commercial License Usage
     ** Licensees holding valid commercial Qt licenses may use this file in
     ** accordance with the commercial license agreement provided with the
     ** Software or, alternatively, in accordance with the terms contained in
     ** a written agreement between you and The Qt Company. For licensing terms
     ** and conditions see https://www.qt.io/terms-conditions. For further
     ** information use the contact form at https://www.qt.io/contact-us.
     **
     ** BSD License Usage
     ** Alternatively, you may use this file under the terms of the BSD license
     ** as follows:
     **
     ** "Redistribution and use in source and binary forms, with or without
     ** modification, are permitted provided that the following conditions are
     ** met:
     **   * Redistributions of source code must retain the above copyright
     **     notice, this list of conditions and the following disclaimer.
     **   * Redistributions in binary form must reproduce the above copyright
     **     notice, this list of conditions and the following disclaimer in
     **     the documentation and/or other materials provided with the
     **     distribution.
     **   * Neither the name of The Qt Company Ltd nor the names of its
     **     contributors may be used to endorse or promote products derived
     **     from this software without specific prior written permission.
     **
     **
     ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
     ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
     ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
     ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
     ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
     ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
     ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
     ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
     **
     ** $QT_END_LICENSE$
     **
     ****************************************************************************/

     import QtQuick 2.0

     Rectangle {
         width: 400; height: 240
         color: "white"

         ListModel {
             id: appModel
             ListElement { name: "Music"; icon: "pics/AudioPlayer_48.png" }
             ListElement { name: "Movies"; icon: "pics/VideoPlayer_48.png" }
             ListElement { name: "Camera"; icon: "pics/Camera_48.png" }
             ListElement { name: "Calendar"; icon: "pics/DateBook_48.png" }
             ListElement { name: "Messaging"; icon: "pics/EMail_48.png" }
             ListElement { name: "Todo List"; icon: "pics/TodoList_48.png" }
             ListElement { name: "Contacts"; icon: "pics/AddressBook_48.png" }
         }

         Component {
             id: appDelegate
             Item {
                 width: 100; height: 100
                 scale: PathView.iconScale

                 Image {
                     id: myIcon
                     y: 20; anchors.horizontalCenter: parent.horizontalCenter
                     source: icon
                 }
                 Text {
                     anchors { top: myIcon.bottom; horizontalCenter: parent.horizontalCenter }
                     text: name
                 }

                 MouseArea {
                     anchors.fill: parent
                     onClicked: view.currentIndex = index
                 }
             }
         }

         Component {
             id: appHighlight
             Rectangle { width: 80; height: 80; color: "lightsteelblue" }
         }

         PathView {
             id: view
             anchors.fill: parent
             highlight: appHighlight
             preferredHighlightBegin: 0.5
             preferredHighlightEnd: 0.5
             focus: true
             model: appModel
             delegate: appDelegate
             path: Path {
                 startX: 10
                 startY: 50
                 PathAttribute { name: "iconScale"; value: 0.5 }
                 PathQuad { x: 200; y: 150; controlX: 50; controlY: 200 }
                 PathAttribute { name: "iconScale"; value: 1.0 }
                 PathQuad { x: 390; y: 50; controlX: 350; controlY: 200 }
                 PathAttribute { name: "iconScale"; value: 0.5 }
             }
         }
     }