main.qml Example File | Qt Quick 5.12.12

- Qt 5.12
- Qt Quick
- Qt Quick TableView examples - Conway’s Game of Life
- main.qml Example File
- Qt 5.12.12 Reference Documentation

# main.qml Example File

tableview/gameoflife/main.qml

     /****************************************************************************
     **
     ** Copyright (C) 2018 The Qt Company Ltd.
     ** Contact: https://www.qt.io/licensing/
     **
     ** This file is part of the examples of the Qt Toolkit.
     **
     ** $QT_BEGIN_LICENSE:BSD$
     ** Commercial License Usage
     ** Licensees holding valid commercial Qt licenses may use this file in
     ** accordance with the commercial license agreement provided with the
     ** Software or, alternatively, in accordance with the terms contained in
     ** a written agreement between you and The Qt Company. For licensing terms
     ** and conditions see https://www.qt.io/terms-conditions. For further
     ** information use the contact form at https://www.qt.io/contact-us.
     **
     ** BSD License Usage
     ** Alternatively, you may use this file under the terms of the BSD license
     ** as follows:
     **
     ** "Redistribution and use in source and binary forms, with or without
     ** modification, are permitted provided that the following conditions are
     ** met:
     **   * Redistributions of source code must retain the above copyright
     **     notice, this list of conditions and the following disclaimer.
     **   * Redistributions in binary form must reproduce the above copyright
     **     notice, this list of conditions and the following disclaimer in
     **     the documentation and/or other materials provided with the
     **     distribution.
     **   * Neither the name of The Qt Company Ltd nor the names of its
     **     contributors may be used to endorse or promote products derived
     **     from this software without specific prior written permission.
     **
     **
     ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
     ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
     ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
     ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
     ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
     ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
     ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
     ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
     **
     ** $QT_END_LICENSE$
     **
     ****************************************************************************/

     import QtQuick 2.12
     import QtQuick.Window 2.3
     import QtQuick.Controls 2.2
     import QtQuick.Layouts 1.3
     import GameOfLifeModel 1.0

     ApplicationWindow {
         id: root
         visible: true
         width: 760
         height: 810
         minimumWidth: 475
         minimumHeight: 300

         color: "#09102B"
         title: qsTr("Conway’s Game of Life")

         TableView {
             id: tableView
             anchors.fill: parent

             rowSpacing: 1
             columnSpacing: 1

             ScrollBar.horizontal: ScrollBar {}
             ScrollBar.vertical: ScrollBar {}

             delegate: Rectangle {
                 id: cell
                 implicitWidth: 15
                 implicitHeight: 15

                 color: model.value ? "#f3f3f4" : "#b5b7bf"

                 MouseArea {
                     anchors.fill: parent
                     onClicked: model.value = !model.value
                 }
             }

             model: GameOfLifeModel {
                 id: gameOfLifeModel
             }

             contentX: (contentWidth - width) / 2;
             contentY: (contentHeight - height) / 2;
         }

         footer: Rectangle {
             signal nextStep

             id: footer
             height: 50
             color: "#F3F3F4"

             RowLayout {
                 anchors.centerIn: parent

                 Button {
                     text: qsTr("Next")
                     onClicked: gameOfLifeModel.nextStep()
                 }

                 Item {
                     width: 50
                 }

                 Slider {
                     id: slider
                     x: 245
                     y: 17
                     from: 0
                     to: 1
                     value: 0.9
                 }

                 Button {
                     text: timer.running ? "❙❙" : "▶️"
                     onClicked: timer.running = !timer.running
                 }
             }

             Timer {
                 id: timer
                 interval: 1000 - (980 * slider.value)
                 running: true
                 repeat: true

                 onTriggered: gameOfLifeModel.nextStep()
             }
         }

         Component.onCompleted: {
             gameOfLifeModel.loadFile(":/gosperglidergun.cells");
         }
     }